build/cmake/FindXDIGEST.cmake

find_path(XDIGEST_INCLUDE_DIR
  NAMES "xdigest.h"
  PATH_SUFFIXES
    "include/xdigest"
)

find_library(XDIGEST_LIBRARY
  NAMES "xdigest"
  PATH_SUFFIXES "lib"
)

if(XDIGEST_INCLUDE_DIR AND EXISTS "${XDIGEST_INCLUDE_DIR}/xdigest.h")
    file(
      STRINGS "${XDIGEST_INCLUDE_DIR}/xdigest.h" VERSION_STRINGS
      REGEX "#define (XDIG_VERSION_MAJOR|XDIG_VERSION_MINOR|XDIG_VERSION_PATCH)"
    )

    string(REGEX REPLACE ".*XDIG_VERSION_MAJOR +([0-9]+).*" "\\1" XDIG_VERSION_MAJOR ${VERSION_STRINGS})
    string(REGEX REPLACE ".*XDIG_VERSION_MINOR +([0-9]+).*" "\\1" XDIG_VERSION_MINOR ${VERSION_STRINGS})
    string(REGEX REPLACE ".*XDIG_VERSION_PATCH +([0-9]+).*" "\\1" XDIG_VERSION_PATCH ${VERSION_STRINGS})

    set(XDIGEST_VERSION "${XDIG_VERSION_MAJOR}.${XDIG_VERSION_MINOR}.${XDIG_VERSION_PATCH}")
endif()

mark_as_advanced(
  XDIGEST_INCLUDE_DIR
  XDIGEST_LIBRARY
)

include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(
  XDIGEST
  REQUIRED_VARS
    XDIGEST_LIBRARY
    XDIGEST_INCLUDE_DIR
  VERSION_VAR
    XDIGEST_VERSION
)

if(XDIGEST_FOUND)
  add_library(XDIGEST::XDIGEST IMPORTED STATIC)

  set_target_properties(XDIGEST::XDIGEST PROPERTIES
    IMPORTED_LOCATION ${XDIGEST_LIBRARY}
    INTERFACE_INCLUDE_DIRECTORIES ${XDIGEST_INCLUDE_DIR}
  )
endif()