gradle/ide/intellij-idea.gradle

/*
 * Licensed to the Apache Software Foundation (ASF) under one or more
 * contributor license agreements.  See the NOTICE file distributed with
 * this work for additional information regarding copyright ownership.
 * The ASF licenses this file to You under the Apache License, Version 2.0
 * (the "License"); you may not use this file except in compliance with
 * the License.  You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

// Try to detect IntelliJ model loader ("reimport") early.
def isIdea = System.getProperty("idea.active") != null ||
    gradle.startParameter.taskNames.contains('idea') ||
    gradle.startParameter.taskNames.contains('cleanIdea')

if (isIdea) {
  logger.warn("IntelliJ Idea IDE detected.")
}

allprojects {
  apply plugin: 'idea'

  idea {
    module {
      outputDir file('build/idea/classes/main')
      testOutputDir file('build/idea/classes/test')
      downloadSources = true
    }
  }
}

// Remove tools source set entirely if we're running under IntelliJ. Otherwise
// files that reference ant can't be compiled.
if (isIdea) {
  configure(project(":solr:solr-ref-guide")) {
    afterEvaluate {
      sourceSets {
        main {
          java {
            srcDirs = []
          }
        }
      }
    }
  }
}