| |
| dnl APACHE_HELP_STRING(LHS, RHS) |
| dnl Autoconf 2.50 can not handle substr correctly. It does have |
| dnl AC_HELP_STRING, so let's try to call it if we can. |
| dnl Note: this define must be on one line so that it can be properly returned |
| dnl as the help string. |
| AC_DEFUN(APACHE_HELP_STRING,[ifelse(regexp(AC_ACVERSION, 2\.1), -1, AC_HELP_STRING($1,$2),[ ]$1 substr([ ],len($1))$2)])dnl |
| |
| dnl APACHE_SUBST(VARIABLE) |
| dnl Makes VARIABLE available in generated files |
| dnl (do not use @variable@ in Makefiles, but $(variable)) |
| AC_DEFUN(APACHE_SUBST,[ |
| APACHE_VAR_SUBST="$APACHE_VAR_SUBST $1" |
| AC_SUBST($1) |
| ]) |
| |
| dnl APACHE_FAST_OUTPUT(FILENAME) |
| dnl Perform substitutions on FILENAME (Makefiles only) |
| AC_DEFUN(APACHE_FAST_OUTPUT,[ |
| APACHE_FAST_OUTPUT_FILES="$APACHE_FAST_OUTPUT_FILES $1" |
| ]) |
| |
| dnl APACHE_GEN_CONFIG_VARS |
| dnl Creates config_vars.mk |
| AC_DEFUN(APACHE_GEN_CONFIG_VARS,[ |
| APACHE_SUBST(abs_srcdir) |
| APACHE_SUBST(bindir) |
| APACHE_SUBST(sbindir) |
| APACHE_SUBST(cgidir) |
| APACHE_SUBST(logfiledir) |
| APACHE_SUBST(exec_prefix) |
| APACHE_SUBST(datadir) |
| APACHE_SUBST(localstatedir) |
| APACHE_SUBST(mandir) |
| APACHE_SUBST(libdir) |
| APACHE_SUBST(libexecdir) |
| APACHE_SUBST(htdocsdir) |
| APACHE_SUBST(manualdir) |
| APACHE_SUBST(includedir) |
| APACHE_SUBST(errordir) |
| APACHE_SUBST(iconsdir) |
| APACHE_SUBST(sysconfdir) |
| APACHE_SUBST(installbuilddir) |
| APACHE_SUBST(runtimedir) |
| APACHE_SUBST(proxycachedir) |
| APACHE_SUBST(other_targets) |
| APACHE_SUBST(progname) |
| APACHE_SUBST(prefix) |
| APACHE_SUBST(AWK) |
| APACHE_SUBST(CC) |
| APACHE_SUBST(CPP) |
| APACHE_SUBST(CXX) |
| APACHE_SUBST(CPPFLAGS) |
| APACHE_SUBST(CFLAGS) |
| APACHE_SUBST(CXXFLAGS) |
| APACHE_SUBST(LTFLAGS) |
| APACHE_SUBST(LDFLAGS) |
| APACHE_SUBST(LT_LDFLAGS) |
| APACHE_SUBST(SH_LDFLAGS) |
| APACHE_SUBST(HTTPD_LDFLAGS) |
| APACHE_SUBST(UTIL_LDFLAGS) |
| APACHE_SUBST(LIBS) |
| APACHE_SUBST(DEFS) |
| APACHE_SUBST(INCLUDES) |
| APACHE_SUBST(NOTEST_CPPFLAGS) |
| APACHE_SUBST(NOTEST_CFLAGS) |
| APACHE_SUBST(NOTEST_CXXFLAGS) |
| APACHE_SUBST(NOTEST_LDFLAGS) |
| APACHE_SUBST(NOTEST_LIBS) |
| APACHE_SUBST(EXTRA_CPPFLAGS) |
| APACHE_SUBST(EXTRA_CFLAGS) |
| APACHE_SUBST(EXTRA_CXXFLAGS) |
| APACHE_SUBST(EXTRA_LDFLAGS) |
| APACHE_SUBST(EXTRA_LIBS) |
| APACHE_SUBST(EXTRA_INCLUDES) |
| APACHE_SUBST(LIBTOOL) |
| APACHE_SUBST(SHELL) |
| APACHE_SUBST(RSYNC) |
| APACHE_SUBST(MODULE_DIRS) |
| APACHE_SUBST(MODULE_CLEANDIRS) |
| APACHE_SUBST(PORT) |
| APACHE_SUBST(SSLPORT) |
| APACHE_SUBST(nonssl_listen_stmt_1) |
| APACHE_SUBST(nonssl_listen_stmt_2) |
| APACHE_SUBST(CORE_IMPLIB_FILE) |
| APACHE_SUBST(CORE_IMPLIB) |
| APACHE_SUBST(SH_LIBS) |
| APACHE_SUBST(SH_LIBTOOL) |
| APACHE_SUBST(MK_IMPLIB) |
| APACHE_SUBST(MKDEP) |
| APACHE_SUBST(INSTALL_PROG_FLAGS) |
| APACHE_SUBST(DSO_MODULES) |
| APACHE_SUBST(APR_BINDIR) |
| APACHE_SUBST(APR_INCLUDEDIR) |
| APACHE_SUBST(APR_VERSION) |
| APACHE_SUBST(APR_CONFIG) |
| APACHE_SUBST(APU_BINDIR) |
| APACHE_SUBST(APU_INCLUDEDIR) |
| APACHE_SUBST(APU_VERSION) |
| APACHE_SUBST(APU_CONFIG) |
| |
| abs_srcdir="`(cd $srcdir && pwd)`" |
| |
| echo creating config_vars.mk |
| test -d build || $mkdir_p build |
| > build/config_vars.mk |
| for i in $APACHE_VAR_SUBST; do |
| eval echo "$i = \$$i" >> build/config_vars.mk |
| done |
| ]) |
| |
| dnl APACHE_GEN_MAKEFILES |
| dnl Creates Makefiles |
| AC_DEFUN(APACHE_GEN_MAKEFILES,[ |
| $SHELL $srcdir/build/fastgen.sh $srcdir $ac_cv_mkdir_p $BSD_MAKEFILE $APACHE_FAST_OUTPUT_FILES |
| ]) |
| |
| dnl ## APACHE_OUTPUT(file) |
| dnl ## adds "file" to the list of files generated by AC_OUTPUT |
| dnl ## This macro can be used several times. |
| AC_DEFUN(APACHE_OUTPUT, [ |
| APACHE_OUTPUT_FILES="$APACHE_OUTPUT_FILES $1" |
| ]) |
| |
| dnl |
| dnl APACHE_TYPE_RLIM_T |
| dnl |
| dnl If rlim_t is not defined, define it to int |
| dnl |
| AC_DEFUN(APACHE_TYPE_RLIM_T, [ |
| AC_CACHE_CHECK([for rlim_t], ac_cv_type_rlim_t, [ |
| AC_TRY_COMPILE([ |
| #include <sys/types.h> |
| #include <sys/time.h> |
| #include <sys/resource.h> |
| ], [rlim_t spoon;], [ |
| ac_cv_type_rlim_t=yes |
| ],[ac_cv_type_rlim_t=no |
| ]) |
| ]) |
| if test "$ac_cv_type_rlim_t" = "no" ; then |
| AC_DEFINE(rlim_t, int, |
| [Define to 'int' if <sys/resource.h> doesn't define it for us]) |
| fi |
| ]) |
| |
| dnl APACHE_MODPATH_INIT(modpath) |
| AC_DEFUN(APACHE_MODPATH_INIT,[ |
| current_dir=$1 |
| modpath_current=modules/$1 |
| modpath_static= |
| modpath_shared= |
| test -d $1 || $srcdir/build/mkdir.sh $modpath_current |
| > $modpath_current/modules.mk |
| ])dnl |
| dnl |
| AC_DEFUN(APACHE_MODPATH_FINISH,[ |
| echo "DISTCLEAN_TARGETS = modules.mk" >> $modpath_current/modules.mk |
| echo "static = $modpath_static" >> $modpath_current/modules.mk |
| echo "shared = $modpath_shared" >> $modpath_current/modules.mk |
| if test ! -z "$modpath_static" -o ! -z "$modpath_shared"; then |
| MODULE_DIRS="$MODULE_DIRS $current_dir" |
| else |
| MODULE_CLEANDIRS="$MODULE_CLEANDIRS $current_dir" |
| fi |
| APACHE_FAST_OUTPUT($modpath_current/Makefile) |
| ])dnl |
| dnl |
| dnl APACHE_MODPATH_ADD(name[, shared[, objects [, ldflags[, libs]]]]) |
| AC_DEFUN(APACHE_MODPATH_ADD,[ |
| if test -z "$3"; then |
| objects="mod_$1.lo" |
| else |
| objects="$3" |
| fi |
| |
| if test -z "$module_standalone"; then |
| if test -z "$2"; then |
| # The filename of a convenience library must have a "lib" prefix: |
| libname="libmod_$1.la" |
| BUILTIN_LIBS="$BUILTIN_LIBS $modpath_current/$libname" |
| modpath_static="$modpath_static $libname" |
| cat >>$modpath_current/modules.mk<<EOF |
| $libname: $objects |
| \$(MOD_LINK) $objects $5 |
| EOF |
| else |
| apache_need_shared=yes |
| libname="mod_$1.la" |
| shobjects=`echo $objects | sed 's/\.lo/.slo/g'` |
| modpath_shared="$modpath_shared $libname" |
| cat >>$modpath_current/modules.mk<<EOF |
| $libname: $shobjects |
| \$(SH_LINK) -rpath \$(libexecdir) -module -avoid-version $4 $objects $5 |
| EOF |
| fi |
| fi |
| ])dnl |
| |
| dnl |
| dnl APACHE_MODULE(name, helptext[, objects[, structname[, default[, config]]]]) |
| dnl |
| dnl default is one of: |
| dnl yes -- enabled by default. user must explicitly disable. |
| dnl no -- disabled under default, most, all. user must explicitly enable. |
| dnl most -- disabled by default. enabled explicitly or with most or all. |
| dnl static -- enabled as static by default, must be explicitly changed. |
| dnl "" -- disabled under default, most. enabled explicitly or with all. |
| dnl |
| dnl basically: yes/no is a hard setting. "most" means follow the "most" |
| dnl setting. otherwise, fall under the "all" setting. |
| dnl explicit yes/no always overrides. |
| dnl |
| AC_DEFUN(APACHE_MODULE,[ |
| AC_MSG_CHECKING(whether to enable mod_$1) |
| define([optname],[--]ifelse($5,yes,disable,enable)[-]translit($1,_,-))dnl |
| AC_ARG_ENABLE(translit($1,_,-),APACHE_HELP_STRING(optname(),$2),,enable_$1=ifelse($5,,maybe-all,$5)) |
| undefine([optname])dnl |
| _apmod_extra_msg="" |
| dnl When --enable-modules=most is set and the module was not explicitly |
| dnl requested, allow a module to disable itself if its pre-reqs fail. |
| if test "$module_selection" = "most" -a "$enable_$1" = "most"; then |
| _apmod_error_fatal="no" |
| else |
| _apmod_error_fatal="yes" |
| fi |
| if test "$enable_$1" = "static"; then |
| enable_$1=yes |
| elif test "$enable_$1" = "yes"; then |
| enable_$1=$module_default |
| _apmod_extra_msg=" ($module_selection)" |
| elif test "$enable_$1" = "most"; then |
| if test "$module_selection" = "most" -o "$module_selection" = "all"; then |
| enable_$1=$module_default |
| _apmod_extra_msg=" ($module_selection)" |
| elif test "$enable_$1" != "yes"; then |
| enable_$1=no |
| fi |
| elif test "$enable_$1" = "maybe-all"; then |
| if test "$module_selection" = "all"; then |
| enable_$1=$module_default |
| _apmod_extra_msg=" (all)" |
| else |
| enable_$1=no |
| fi |
| fi |
| if test "$enable_$1" != "no"; then |
| dnl If we plan to enable it, allow the module to run some autoconf magic |
| dnl that may disable it because of missing dependencies. |
| ifelse([$6],,:,[AC_MSG_RESULT([checking dependencies]) |
| $6 |
| AC_MSG_CHECKING(whether to enable mod_$1) |
| if test "$enable_$1" = "no"; then |
| if test "$_apmod_error_fatal" = "no"; then |
| _apmod_extra_msg=" (disabled)" |
| else |
| AC_MSG_ERROR([mod_$1 has been requested but can not be built due to prerequisite failures]) |
| fi |
| fi]) |
| fi |
| AC_MSG_RESULT($enable_$1$_apmod_extra_msg) |
| if test "$enable_$1" != "no"; then |
| case "$enable_$1" in |
| shared*) |
| enable_$1=`echo $enable_$1|sed 's/shared,*//'` |
| sharedobjs=yes |
| shared=yes |
| DSO_MODULES="$DSO_MODULES $1" |
| ;; |
| *) |
| MODLIST="$MODLIST ifelse($4,,$1,$4)" |
| if test "$1" = "so"; then |
| sharedobjs=yes |
| fi |
| shared="";; |
| esac |
| define([modprefix], [MOD_]translit($1, [a-z-], [A-Z_])) |
| APACHE_MODPATH_ADD($1, $shared, $3,, [\$(]modprefix[_LDADD)]) |
| APACHE_SUBST(modprefix[_LDADD]) |
| undefine([modprefix]) |
| fi |
| ])dnl |
| |
| dnl |
| dnl APACHE_ENABLE_MODULES |
| dnl |
| AC_DEFUN(APACHE_ENABLE_MODULES,[ |
| module_selection=default |
| module_default=yes |
| |
| AC_ARG_ENABLE(modules, |
| APACHE_HELP_STRING(--enable-modules=MODULE-LIST,Space-separated list of modules to enable | "all" | "most"),[ |
| for i in $enableval; do |
| if test "$i" = "all" -o "$i" = "most"; then |
| module_selection=$i |
| else |
| i=`echo $i | sed 's/-/_/g'` |
| eval "enable_$i=yes" |
| fi |
| done |
| ]) |
| |
| AC_ARG_ENABLE(mods-shared, |
| APACHE_HELP_STRING(--enable-mods-shared=MODULE-LIST,Space-separated list of shared modules to enable | "all" | "most"),[ |
| for i in $enableval; do |
| if test "$i" = "all" -o "$i" = "most"; then |
| module_selection=$i |
| module_default=shared |
| else |
| i=`echo $i | sed 's/-/_/g'` |
| eval "enable_$i=shared" |
| fi |
| done |
| ]) |
| ]) |
| |
| AC_DEFUN(APACHE_REQUIRE_CXX,[ |
| if test -z "$apache_cxx_done"; then |
| AC_PROG_CXX |
| AC_PROG_CXXCPP |
| apache_cxx_done=yes |
| fi |
| ]) |
| |
| dnl |
| dnl APACHE_CHECK_SSL_TOOLKIT |
| dnl |
| dnl Configure for the detected openssl/ssl-c toolkit installation, giving |
| dnl preference to "--with-ssl=<path>" if it was specified. |
| dnl |
| AC_DEFUN(APACHE_CHECK_SSL_TOOLKIT,[ |
| if test "x$ap_ssltk_configured" = "x"; then |
| dnl initialise the variables we use |
| ap_ssltk_base="" |
| ap_ssltk_libs="" |
| ap_ssltk_type="" |
| |
| dnl Determine the SSL/TLS toolkit's base directory, if any |
| AC_MSG_CHECKING([for SSL/TLS toolkit base]) |
| AC_ARG_WITH(sslc, APACHE_HELP_STRING(--with-sslc=DIR,RSA SSL-C SSL/TLS toolkit), [ |
| dnl If --with-sslc specifies a directory, we use that directory or fail |
| if test "x$withval" != "xyes" -a "x$withval" != "x"; then |
| dnl This ensures $withval is actually a directory and that it is absolute |
| ap_ssltk_base="`cd $withval ; pwd`" |
| fi |
| ap_ssltk_type="sslc" |
| ]) |
| AC_ARG_WITH(ssl, APACHE_HELP_STRING(--with-ssl=DIR,OpenSSL SSL/TLS toolkit), [ |
| dnl If --with-ssl specifies a directory, we use that directory or fail |
| if test "x$withval" != "xyes" -a "x$withval" != "x"; then |
| dnl This ensures $withval is actually a directory and that it is absolute |
| ap_ssltk_base="`cd $withval ; pwd`" |
| fi |
| ]) |
| if test "x$ap_ssltk_base" = "x"; then |
| AC_MSG_RESULT(none) |
| else |
| AC_MSG_RESULT($ap_ssltk_base) |
| fi |
| |
| dnl Run header and version checks |
| saved_CPPFLAGS="$CPPFLAGS" |
| saved_LIBS="$LIBS" |
| if test "x$ap_ssltk_base" != "x"; then |
| APR_ADDTO(CPPFLAGS, [-I$ap_ssltk_base/include]) |
| APR_ADDTO(INCLUDES, [-I$ap_ssltk_base/include]) |
| APR_ADDTO(LDFLAGS, [-L$ap_ssltk_base/lib]) |
| if test "x$ap_platform_runtime_link_flag" != "x"; then |
| APR_ADDTO(LDFLAGS, [$ap_platform_runtime_link_flag$ap_ssltk_base/lib]) |
| fi |
| fi |
| if test "x$ap_ssltk_type" = "x"; then |
| AC_MSG_CHECKING([for OpenSSL version]) |
| dnl First check for manditory headers |
| AC_CHECK_HEADERS([openssl/opensslv.h openssl/ssl.h], [ap_ssltk_type="openssl"], []) |
| if test "$ap_ssltk_type" = "openssl"; then |
| dnl so it's OpenSSL - test for a good version |
| AC_TRY_COMPILE([#include <openssl/opensslv.h>],[ |
| #if !defined(OPENSSL_VERSION_NUMBER) |
| #error "Missing openssl version" |
| #endif |
| #if (OPENSSL_VERSION_NUMBER < 0x009060af) \ |
| || ((OPENSSL_VERSION_NUMBER > 0x00907000) && (OPENSSL_VERSION_NUMBER < 0x0090702f)) |
| #error "Insecure openssl version " OPENSSL_VERSION_TEXT |
| #endif], |
| [AC_MSG_RESULT(OK)], |
| [dnl Replace this with OPENSSL_VERSION_TEXT from opensslv.h? |
| AC_MSG_RESULT([not encouraging]) |
| echo "WARNING: OpenSSL version may contain security vulnerabilities!" |
| echo " Ensure the latest security patches have been applied!" |
| ]) |
| else |
| AC_MSG_RESULT([no OpenSSL headers found]) |
| fi |
| fi |
| if test "$ap_ssltk_type" != "openssl"; then |
| dnl Might be SSL-C - report, then test anything relevant |
| AC_MSG_CHECKING([for SSL-C version]) |
| AC_CHECK_HEADERS([sslc.h], [ap_ssltk_type="sslc"], [ap_ssltk_type=""]) |
| if test "$ap_ssltk_type" = "sslc"; then |
| ap_ssltk_libs="-lsslc" |
| AC_MSG_CHECKING([for SSL-C version]) |
| AC_TRY_COMPILE([#include <sslc.h>],[ |
| #if !defined(SSLC_VERSION_NUMBER) |
| #error "Missing SSL-C version" |
| #endif |
| #if SSLC_VERSION_NUMBER < 0x2310 |
| #define stringize_ver(x) #x |
| #error "Insecure SSL-C version " stringize_ver(SSLC_VERSION_NUMBER) |
| #endif], |
| [AC_MSG_RESULT(OK)], |
| [dnl Replace this with SSLC_VERSION_NUMBER? |
| AC_MSG_RESULT([not encouraging]) |
| echo "WARNING: SSL-C version may contain security vulnerabilities!" |
| echo " Ensure the latest security patches have been applied!" |
| ]) |
| else |
| AC_MSG_RESULT([no SSL-C headers found]) |
| fi |
| fi |
| if test "x$ap_ssltk_type" = "x"; then |
| AC_MSG_ERROR([...No recognized SSL/TLS toolkit detected]) |
| fi |
| |
| if test "$ap_ssltk_type" = "openssl"; then |
| if test "x$ap_ssltk_base" != "x" -a \ |
| -f "${ap_ssltk_base}/lib/pkgconfig/openssl.pc"; then |
| dnl Ensure that the given path is used by pkg-config too, otherwise |
| dnl the system openssl.pc might be picked up instead. |
| PKG_CONFIG_PATH="${ap_ssltk_base}/lib/pkgconfig${PKG_CONFIG_PATH+:}${PKG_CONFIG_PATH}" |
| export PKG_CONFIG_PATH |
| fi |
| if test -n "$PKGCONFIG"; then |
| ap_ssltk_libs="`$PKGCONFIG --libs-only-l openssl`" |
| if test $? -eq 0; then |
| pkglookup="`$PKGCONFIG --cflags-only-I openssl`" |
| APR_ADDTO(CPPFLAGS, [$pkglookup]) |
| APR_ADDTO(INCLUDES, [$pkglookup]) |
| pkglookup="`$PKGCONFIG --libs-only-L --libs-only-other openssl`" |
| APR_ADDTO(LDFLAGS, [$pkglookup]) |
| else |
| ap_ssltk_libs="-lssl -lcrypto `$apr_config --libs`" |
| fi |
| else |
| ap_ssltk_libs="-lssl -lcrypto `$apr_config --libs`" |
| fi |
| fi |
| APR_SETVAR(SSL_LIBS, [$ap_ssltk_libs]) |
| APR_ADDTO(LIBS, [$ap_ssltk_libs]) |
| APACHE_SUBST(SSL_LIBS) |
| |
| dnl Run library and function checks |
| liberrors="" |
| if test "$ap_ssltk_type" = "openssl"; then |
| AC_CHECK_HEADERS([openssl/engine.h]) |
| AC_CHECK_FUNCS([SSLeay_version SSL_CTX_new], [], [liberrors="yes"]) |
| AC_CHECK_FUNCS([ENGINE_init ENGINE_load_builtin_engines]) |
| else |
| AC_CHECK_FUNCS([SSLC_library_version SSL_CTX_new], [], [liberrors="yes"]) |
| AC_CHECK_FUNCS(SSL_set_state) |
| fi |
| AC_CHECK_FUNCS(SSL_set_cert_store) |
| dnl restore |
| CPPFLAGS="$saved_CPPFLAGS" |
| LIBS="$saved_LIBS" |
| if test "x$liberrors" != "x"; then |
| AC_MSG_ERROR([... Error, SSL/TLS libraries were missing or unusable]) |
| fi |
| |
| dnl Adjust apache's configuration based on what we found above. |
| dnl (a) define preprocessor symbols |
| if test "$ap_ssltk_type" = "openssl"; then |
| AC_DEFINE(HAVE_OPENSSL, 1, [Define if SSL is supported using OpenSSL]) |
| else |
| AC_DEFINE(HAVE_SSLC, 1, [Define if SSL is supported using SSL-C]) |
| fi |
| fi |
| ]) |
| |
| dnl |
| dnl APACHE_EXPORT_ARGUMENTS |
| dnl Export (via APACHE_SUBST) the various path-related variables that |
| dnl apache will use while generating scripts like autoconf and apxs and |
| dnl the default config file. |
| |
| AC_DEFUN(APACHE_SUBST_EXPANDED_ARG,[ |
| APR_EXPAND_VAR(exp_$1, [$]$1) |
| APACHE_SUBST(exp_$1) |
| APR_PATH_RELATIVE(rel_$1, [$]exp_$1, ${prefix}) |
| APACHE_SUBST(rel_$1) |
| ]) |
| |
| AC_DEFUN(APACHE_EXPORT_ARGUMENTS,[ |
| APACHE_SUBST_EXPANDED_ARG(exec_prefix) |
| APACHE_SUBST_EXPANDED_ARG(bindir) |
| APACHE_SUBST_EXPANDED_ARG(sbindir) |
| APACHE_SUBST_EXPANDED_ARG(libdir) |
| APACHE_SUBST_EXPANDED_ARG(libexecdir) |
| APACHE_SUBST_EXPANDED_ARG(mandir) |
| APACHE_SUBST_EXPANDED_ARG(sysconfdir) |
| APACHE_SUBST_EXPANDED_ARG(datadir) |
| APACHE_SUBST_EXPANDED_ARG(installbuilddir) |
| APACHE_SUBST_EXPANDED_ARG(errordir) |
| APACHE_SUBST_EXPANDED_ARG(iconsdir) |
| APACHE_SUBST_EXPANDED_ARG(htdocsdir) |
| APACHE_SUBST_EXPANDED_ARG(manualdir) |
| APACHE_SUBST_EXPANDED_ARG(cgidir) |
| APACHE_SUBST_EXPANDED_ARG(includedir) |
| APACHE_SUBST_EXPANDED_ARG(localstatedir) |
| APACHE_SUBST_EXPANDED_ARG(runtimedir) |
| APACHE_SUBST_EXPANDED_ARG(logfiledir) |
| APACHE_SUBST_EXPANDED_ARG(proxycachedir) |
| ]) |
| |
| dnl |
| dnl APACHE_CHECK_APxVER({apr|apu}, major, minor, |
| dnl [actions-if-ok], [actions-if-not-ok]) |
| dnl |
| dnl Checks for APR or APR-util of given major/minor version or later; |
| dnl if so, runs actions-if-ok; otherwise runs actions-if-not-ok if given. |
| dnl If the version is not satisfactory and actions-if-not-ok is not |
| dnl given, then an error is printed and the configure script is aborted. |
| dnl |
| dnl The first argument must be [apr] or [apu]. |
| dnl |
| AC_DEFUN([APACHE_CHECK_APxVER], [ |
| define(ap_ckver_major, translit($1, [apru], [APRU])[_MAJOR_VERSION]) |
| define(ap_ckver_minor, translit($1, [apru], [APRU])[_MINOR_VERSION]) |
| define(ap_ckver_cvar, [ap_cv_$1ver$2$3]) |
| define(ap_ckver_name, ifelse([$1],[apr],[APR],[APR-util])) |
| |
| ap_ckver_CPPFLAGS="$CPPFLAGS" |
| CPPFLAGS="$CPPFLAGS `$[$1]_config --includes`" |
| |
| AC_CACHE_CHECK([for ap_ckver_name version $2.$3.0 or later], ap_ckver_cvar, [ |
| AC_EGREP_CPP([good], [ |
| #include <$1_version.h> |
| #if ]ap_ckver_major[ > $2 || (]ap_ckver_major[ == $2 && ]ap_ckver_minor[ >= $3) |
| good |
| #endif |
| ], [ap_ckver_cvar=yes], [ap_ckver_cvar=no])]) |
| |
| if test "$ap_ckver_cvar" = "yes"; then |
| ifelse([$4],[],[:],[$4]) |
| else |
| ifelse([$5],[],[AC_MSG_ERROR([ap_ckver_name version $2.$3.0 or later is required])], [$5]) |
| fi |
| |
| CPPFLAGS="$ap_ckver_CPPFLAGS" |
| |
| undefine([ap_ckver_major]) |
| undefine([ap_ckver_minor]) |
| undefine([ap_ckver_cvar]) |
| undefine([ap_ckver_name]) |
| ]) |
| |
| dnl |
| dnl APACHE_CHECK_VOID_PTR_LEN |
| dnl |
| dnl Checks if the size of a void pointer is at least as big as a "long" |
| dnl integer type. |
| dnl |
| AC_DEFUN([APACHE_CHECK_VOID_PTR_LEN], [ |
| |
| AC_CACHE_CHECK([for void pointer length], [ap_cv_void_ptr_lt_long], |
| [AC_TRY_RUN([ |
| int main(void) |
| { |
| return sizeof(void *) < sizeof(long); |
| }], [ap_cv_void_ptr_lt_long=no], [ap_cv_void_ptr_lt_long=yes], |
| [ap_cv_void_ptr_lt_long=yes])]) |
| |
| if test "$ap_cv_void_ptr_lt_long" = "yes"; then |
| AC_MSG_ERROR([Size of "void *" is less than size of "long"]) |
| fi |
| ]) |