build-logic/src/main/groovy/org.apache.groovy-stresstest.gradle

/*
 *  Licensed to the Apache Software Foundation (ASF) under one
 *  or more contributor license agreements.  See the NOTICE file
 *  distributed with this work for additional information
 *  regarding copyright ownership.  The ASF licenses this file
 *  to you under the Apache License, Version 2.0 (the
 *  "License"); you may not use this file except in compliance
 *  with the License.  You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 *  Unless required by applicable law or agreed to in writing,
 *  software distributed under the License is distributed on an
 *  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 *  KIND, either express or implied.  See the License for the
 *  specific language governing permissions and limitations
 *  under the License.
 */
plugins {
    id 'groovy'
    id 'org.apache.groovy-common'
    id 'org.apache.groovy-internal'
}

sourceSets {
    stressTest {
        groovy {
            if (!JavaVersion.current().isCompatibleWith(JavaVersion.VERSION_14)) {
                exclude '**/vm14/*'
            }
        }
    }
}

def stressTest = tasks.register("stressTest", Test) {
    description = "Runs the stress tests."
    group = "verification"
    minHeapSize = '512m'
    maxHeapSize = '512m'
    testClassesDirs = sourceSets.stressTest.output.classesDirs
    classpath = sourceSets.stressTest.runtimeClasspath
}

tasks.named('check') {
    dependsOn stressTest
}