subprojects/groovy-groovydoc/build.gradle

/*
 *  Licensed to the Apache Software Foundation (ASF) under one
 *  or more contributor license agreements.  See the NOTICE file
 *  distributed with this work for additional information
 *  regarding copyright ownership.  The ASF licenses this file
 *  to you under the Apache License, Version 2.0 (the
 *  "License"); you may not use this file except in compliance
 *  with the License.  You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 *  Unless required by applicable law or agreed to in writing,
 *  software distributed under the License is distributed on an
 *  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 *  KIND, either express or implied.  See the License for the
 *  specific language governing permissions and limitations
 *  under the License.
 */
plugins {
    id 'org.apache.groovy-library'
}

dependencies {
    api rootProject // GroovydocVisitor extends ClassCodeVisitorSupport...
    api "com.github.javaparser:javaparser-core:${versions.javaParser}" // GroovydocJavaVisitor extends VoidVisitorAdapter...

    implementation projects.groovyTemplates
    implementation projects.groovyDocgenerator

    testImplementation projects.groovyAnt
    testImplementation projects.groovyTest
    testImplementation "org.apache.ant:ant-testutil:${versions.ant}"
}

compileJava {
    doLast {
        mkdir "${sourceSets.main.java.classesDirectory.get().asFile}/META-INF"
    }
}

plugins.withId('eclipse') {
    eclipse.classpath.file.whenMerged {
        entries.removeAll { entry -> entry.path in ['/groovy-ant', '/groovy-xml'] }
    }
}

tasks.named('rat') {
    excludes << '**/stylesheet.css' // MIT license as per NOTICE/LICENSE files
}