wrapper/build.gradle

buildscript {
    ext {
        grailsVersion = project.grailsVersion
    }
    repositories {
        mavenCentral()
        maven { url "https://repo.grails.org/grails/core" }
        maven { url "https://plugins.gradle.org/m2/" }
        if (groovyVersion.endsWith('-SNAPSHOT')) {
            maven {
                name 'JFrog OSS snapshot repo'
                url 'https://oss.jfrog.org/oss-snapshot-local/'
            }
        }
    }
    dependencies {
        classpath "org.grails:grails-gradle-plugin:$grailsGradlePluginVersion"
        classpath 'io.spring.gradle:dependency-management-plugin:1.1.6'
        classpath "io.github.gradle-nexus:publish-plugin:2.0.0"
        classpath "com.bmuschko:gradle-nexus-plugin:2.3.1"
    }
}

group 'org.grails'
version project.projectVersion

ext.pomInfo = {
    delegate.name 'Grails 7 Wrapper'
    delegate.description 'The Grails Wrapper Project'
    delegate.url 'https://github.com/grails/grails-wrapper'

    delegate.licenses {
        delegate.license {
            delegate.name 'The Apache Software License, Version 2.0'
            delegate.url 'https://www.apache.org/licenses/LICENSE-2.0.txt'
            delegate.distribution 'repo'
        }
    }

    delegate.scm {
        delegate.url "scm:git@github.com:grails/grails-wrapper.git"
        delegate.connection "scm:git@github.com:grails/grails-wrapper.git"
        delegate.developerConnection "scm:git@github.com:grails/grails-wrapper.git"
    }

    delegate.developers {
        delegate.developer {
            delegate.id 'graemerocher'
            delegate.name 'Graeme Rocher'
        }
        delegate.developer {
            delegate.id 'jeffscottbrown'
            delegate.name 'Jeff Brown'
        }
        delegate.developer {
            delegate.id 'puneetbehl'
            delegate.name 'Puneet Behl'
        }
    }
}

apply plugin: 'groovy'
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'maven-publish'
apply plugin: 'signing'
apply plugin: "io.spring.dependency-management"

ext {
    grailsVersion = project.grailsVersion
    userOrg = 'grails'
    repo = 'grails-core'
}

configurations {
    groovyDoc.extendsFrom runtimeClasspath

    all {
        resolutionStrategy.dependencySubstitution {
            //update fields plugin used by scaffolding
            substitute(module("org.codehaus.plexus:plexus-sec-dispatcher:2.0")).using(module("org.sonatype.plexus:plexus-sec-dispatcher:1.4"))
        }
    }
}

repositories {
    mavenCentral()
    maven { url "https://repo.grails.org/grails/core" }
    if (groovyVersion.endsWith('-SNAPSHOT')) {
        maven {
            name 'JFrog OSS snapshot repo'
            url 'https://oss.jfrog.org/oss-snapshot-local/'
        }
    }
}

dependencies {
    implementation "org.apache.groovy:groovy:$groovyVersion"
    implementation "org.springframework.boot:spring-boot-cli:$springBootVersion"
    implementation "org.apache.groovy:groovy-ant:$groovyVersion"
    implementation "org.grails:grails-shell:$grailsShellVersion"
    implementation "org.apache.groovy:groovy-templates:$groovyVersion"
}

jar {
    from {
        (configurations.runtimeClasspath).collect {
            it.isDirectory() ? it : zipTree(it)
        }
    }
    manifest {
        attributes 'Main-Class': 'grails.init.RunCommand'
    }

    duplicatesStrategy = DuplicatesStrategy.INCLUDE
}

task sourcesJar(type: Jar) {
    archiveClassifier.set('sources')
    from project.sourceSets.main.allSource
}

task javadocJar(type: Jar) {
    archiveClassifier.set('javadoc')
    from groovydoc.outputs
}

tasks.withType(Groovydoc) {
    groovyClasspath = project.configurations.groovyDoc
    includes = ["grails-wrapper/**"]
}

afterEvaluate {
    signing {
        required { isReleaseVersion && gradle.taskGraph.hasTask("publish") }
        sign publishing.publications.maven
    }
}

tasks.withType(io.github.gradlenexus.publishplugin.InitializeNexusStagingRepository).configureEach {
    shouldRunAfter(tasks.withType(Sign))
}

apply from:'../publishing/grailsCentralPublishing.gradle'