gradle/docs-config.gradle

/*
 *  Licensed to the Apache Software Foundation (ASF) under one
 *  or more contributor license agreements.  See the NOTICE file
 *  distributed with this work for additional information
 *  regarding copyright ownership.  The ASF licenses this file
 *  to you under the Apache License, Version 2.0 (the
 *  "License"); you may not use this file except in compliance
 *  with the License.  You may obtain a copy of the License at
 *
 *    https://www.apache.org/licenses/LICENSE-2.0
 *
 *  Unless required by applicable law or agreed to in writing,
 *  software distributed under the License is distributed on an
 *  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 *  KIND, either express or implied.  See the License for the
 *  specific language governing permissions and limitations
 *  under the License.
 */

configurations.register('documentation') {
    canBeConsumed = false
    canBeResolved = true
    attributes {
        attribute(Category.CATEGORY_ATTRIBUTE, objects.named(Category, Category.LIBRARY))
        attribute(Bundling.BUNDLING_ATTRIBUTE, objects.named(Bundling, Bundling.EXTERNAL))
        attribute(Usage.USAGE_ATTRIBUTE, objects.named(Usage, Usage.JAVA_RUNTIME))
    }
}

dependencies {
    add('documentation', platform("org.apache.grails:grails-bom:$grailsVersion"))
    add('documentation', 'com.github.javaparser:javaparser-core')
    add('documentation', 'org.apache.groovy:groovy')
    add('documentation', 'org.apache.groovy:groovy-groovydoc')
    add('documentation', 'org.apache.groovy:groovy-ant')
    add('documentation', 'org.apache.groovy:groovy-docgenerator')
    add('documentation', 'org.apache.groovy:groovy-templates')
}

tasks.withType(Groovydoc).configureEach {
    it.access = GroovydocAccess.PROTECTED
    it.processScripts = false
    it.includeMainForScripts = false
    it.includeAuthor = false
    it.noTimestamp = true
    it.noVersionStamp = false
    it.groovyClasspath += configurations.documentation
}