settings.gradle

pluginManagement {
    repositories {
        gradlePluginPortal()
        mavenCentral()
    }
}

plugins {
    id "com.gradle.enterprise" version "3.13.2"
    id 'com.gradle.common-custom-user-data-gradle-plugin' version '1.10'
}

gradleEnterprise {
    server = 'https://ge.grails.org'
    buildScan {
        publishAlways()
        publishIfAuthenticated()
        uploadInBackground = System.getenv("CI") == null
        capture {
            taskInputFiles = true
        }
    }
}

buildCache {
    local { enabled = System.getenv('CI') != 'true' }
    remote(HttpBuildCache) {
        push = System.getenv('CI') == 'true'
        enabled = true
        url = 'https://ge.grails.org/cache/'
        credentials {
            username = System.getenv('GRADLE_ENTERPRISE_BUILD_CACHE_NODE_USER')
            password = System.getenv('GRADLE_ENTERPRISE_BUILD_CACHE_NODE_KEY')
        }
    }}


rootProject.name = 'grails-forge'

include 'grails-forge-core'
include 'grails-cli'
include 'test-core'
include 'grails-forge-api'
include 'grails-forge-web-netty'
include 'grails-forge-analytics-postgres'