build.gradle

buildscript {
    repositories {
        maven { url "https://repo.grails.org/grails/core" }
        maven { url = 'https://repository.apache.org/content/repositories/snapshots' }
        if (System.getenv("GITHUB_MAVEN_PASSWORD") && !grailsVersion.endsWith('-SNAPSHOT')) {
            System.out.println("Adding Grails Core Repo")
            maven {
                url = 'https://maven.pkg.github.com/grails/grails-core'
                credentials {
                    username = 'DOES_NOT_MATTER'
                    password = System.getenv("GITHUB_MAVEN_PASSWORD")
                }
            }
        }
    }
    dependencies {
        classpath platform("org.apache.grails:grails-bom:$grailsVersion")
        classpath "org.apache.grails:grails-gradle-plugins"
    }
}

allprojects {
    repositories {
        mavenCentral()
        maven { url "https://repo.grails.org/grails/core" }
        maven { url = 'https://repository.apache.org/content/repositories/snapshots' }
        if (System.getenv("GITHUB_MAVEN_PASSWORD") && !grailsVersion.endsWith('-SNAPSHOT')) {
            System.out.println("Adding Grails Core Repo")
            maven {
                url = 'https://maven.pkg.github.com/grails/grails-core'
                credentials {
                    username = 'DOES_NOT_MATTER'
                    password = System.getenv("GITHUB_MAVEN_PASSWORD")
                }
            }
        }
    }
}

group = "org.apache.grails"
version = project.projectVersion

subprojects {
    if(project.name == 'plugin') {
        version = projectVersion
        group = "org.apache.grails"

        apply plugin:"org.apache.grails.gradle.grails-publish"
        grailsPublish {
            artifactId = 'grails-cache'
            githubSlug = "apache/grails-cache"
            license {
                name = 'Apache-2.0'
            }
            title = "Grails Cache Plugin"
            desc = "Provides AST transformations for caching method calls"
            developers = [jeffbrown: "Jeff Scott Brown", "puneetbehl": "Puneet Behl"]
        }
    }
}