build.gradle

ext.githubProjectName = rootProject.name // Change if github project name is not the same as the root project's name

buildscript {
    repositories { mavenCentral() }
    apply from: file('gradle/buildscript.gradle'), to: buildscript
}

allprojects {
    repositories { mavenCentral() }
}

apply from: file('gradle/convention.gradle')
apply from: file('gradle/maven.gradle')
//apply from: file('gradle/check.gradle')
//apply from: file('gradle/license.gradle')
apply from: file('gradle/release.gradle')

apply plugin: 'idea'
apply plugin: 'eclipse'

subprojects {
    apply plugin: 'idea'
    apply plugin: 'eclipse'

    group = "com.netflix.${githubProjectName}" // TEMPLATE: Set to organization of project

    dependencies {
        compile('org.apache.zookeeper:zookeeper:3.4.5')
        {
            exclude group: 'com.sun.jmx', module: 'jmxri'
            exclude group: 'com.sun.jdmk', module: 'jmxtools'
            exclude group: 'javax.jms', module: 'jms'

            // JLine pulls this in as a compile dependency, they have fixed it in future versions
            exclude group: 'junit', module: 'junit'
        }
        compile     'com.google.guava:guava:11.0.1'
        testCompile 'org.testng:testng:6.1.1'
        testCompile 'log4j:log4j:1.2.16'
    }
}

project(':curator-client')
{
    dependencies
    {
        compile 'org.slf4j:slf4j-api:1.6.4'
        // Original has commons-logging
        testCompile 'org.mockito:mockito-core:1.8.5'
        testCompile project(':curator-test')
    }
}

project(':curator-test')
{
    dependencies
    {
        compile 'org.javassist:javassist:3.15.0-GA'
        compile 'org.apache.commons:commons-math:2.2'
    }
}

project(':curator-framework')
{
    dependencies
    {
        compile project(':curator-client')
        testCompile project(':curator-test')
    }
}

project(':curator-recipes')
{
    dependencies
    {
        compile project(':curator-framework')
        testCompile 'org.mockito:mockito-core:1.8.5'
        testCompile project(':curator-test')
    }
}

project(':curator-x-zkclient-bridge')
{
    dependencies
    {
        compile project(':curator-client')
        compile project(':curator-framework')
        compile ('com.github.sgroschupf:zkclient:0.1')
        {
            exclude group: 'com.sun.jmx', module: 'jmxri'
            exclude group: 'com.sun.jdmk', module: 'jmxtools'
            exclude group: 'javax.jms', module: 'jms'
        }
        testCompile project(':curator-test')
        testCompile 'org.slf4j:slf4j-api:1.6.4'
        testCompile 'org.javassist:javassist:3.15.0-GA'
        testCompile 'commons-io:commons-io:1.4'
        testCompile 'org.mockito:mockito-core:1.8.0'
        testCompile 'junit:junit:4.7'
    }
}

project(':curator-x-discovery')
{
    dependencies
    {
        compile project(':curator-recipes')
        compile 'org.codehaus.jackson:jackson-mapper-asl:1.9.2'
        testCompile project(':curator-test')
    }
}

project(':curator-x-discovery-server')
{
    dependencies
    {
        compile project(':curator-x-discovery')
        compile 'javax.ws.rs:jsr311-api:1.1.1'
        compile 'com.google.inject:guice:3.0'   // only for TypeLiteral - in the future will be replaced by Guava 13
        testCompile project(':curator-test')
        testCompile 'com.sun.jersey:jersey-server:1.11'
        testCompile 'com.sun.jersey:jersey-servlet:1.11'
        testCompile 'com.sun.jersey:jersey-client:1.11'
        testCompile 'com.sun.jersey:jersey-core:1.11'
        testCompile 'net.sf.scannotation:scannotation:1.0.2'
        testCompile ('org.jboss.resteasy:resteasy-jaxrs:2.3.0.GA')
        {
            exclude module: 'scannotation'
        }
        testCompile 'org.mortbay.jetty:jetty:6.1.22'
    }
}

project(':curator-examples')
{
    dependencies
    {
        compile project(':curator-test')
        compile project(':curator-recipes')
        compile project(':curator-x-discovery')
    }
}