cpu-affinity/src/main/affinity/build.gradle

/*
 * Licensed to the Apache Software Foundation (ASF) under one
 * or more contributor license agreements.  See the NOTICE file
 * distributed with this work for additional information
 * regarding copyright ownership.  The ASF licenses this file
 * to you under the Apache License, Version 2.0 (the
 * "License"); you may not use this file except in compliance
 * with the License.  You may obtain a copy of the License at
 *
 *   http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing,
 * software distributed under the License is distributed on an
 * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 * KIND, either express or implied.  See the License for the
 * specific language governing permissions and limitations
 * under the License.
 */
import org.gradle.internal.jvm.Jvm

plugins {
    id 'cpp-library'
}

library {
    binaries.configureEach { CppBinary binary ->
        def compileTask = binary.compileTask.get()
        compileTask.dependsOn project(':cpu-affinity').generateJniHeaders
        compileTask.includes.from("${Jvm.current().javaHome}/include",
                                  project(':cpu-affinity').generateJniHeaders.javahOutputDir)

        def osFamily = binary.targetPlatform.targetMachine.operatingSystemFamily

        if (osFamily.linux) {
            compileTask.includes.from("${Jvm.current().javaHome}/include/linux")
        } else if (osFamily.macOs) {
            compileTask.includes.from("${Jvm.current().javaHome}/include/darwin")
        }

        compileTask.includes.from("${Jvm.current().javaHome}/include/linux")
        compileTask.includes.from("${Jvm.current().javaHome}/include/darwin")
        compileTask.source.from fileTree(dir: "cpp", include: "**/*.c")

        compileTask.compilerArgs.addAll(["-x", "c", "-std=c11"])
    }
}