sdks/java/io/debezium/expansion-service/build.gradle

/*
 * Licensed to the Apache Software Foundation (ASF) under one
 * or more contributor license agreements.  See the NOTICE file
 * distributed with this work for additional information
 * regarding copyright ownership.  The ASF licenses this file
 * to you under the Apache License, Version 2.0 (the
 * License); you may not use this file except in compliance
 * with the License.  You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an AS IS BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

apply plugin: 'org.apache.beam.module'
apply plugin: 'application'
mainClassName = "org.apache.beam.sdk.expansion.service.ExpansionService"

applyJavaNature(
        automaticModuleName: 'org.apache.beam.sdk.io.debezium.expansion.service',
        exportJavadoc: false,
        validateShadowJar: false,
        shadowClosure: {},
        requireJavaVersion: JavaVersion.VERSION_17,
)

description = "Apache Beam :: SDKs :: Java :: IO :: Debezium :: Expansion Service"
ext.summary = "Expansion service serving DebeziumIO"

dependencies {
    implementation project(":sdks:java:expansion-service")
    permitUnusedDeclared project(":sdks:java:expansion-service") // BEAM-11761
    implementation project(":sdks:java:io:debezium")
    permitUnusedDeclared project(":sdks:java:io:debezium") // BEAM-11761
    runtimeOnly library.java.slf4j_jdk14

    // Debezium runtime dependencies
    def debezium_version = '3.1.3.Final'
    runtimeOnly group: 'io.debezium', name: 'debezium-connector-mysql', version: debezium_version
    runtimeOnly group: 'io.debezium', name: 'debezium-connector-postgres', version: debezium_version
    runtimeOnly group: 'io.debezium', name: 'debezium-connector-sqlserver', version: debezium_version
    runtimeOnly group: 'io.debezium', name: 'debezium-connector-oracle', version: debezium_version
    runtimeOnly group: 'io.debezium', name: 'debezium-connector-db2', version: debezium_version
}

// sync with debezium/build.gradle depenency pins
configurations.all {
    resolutionStrategy {
        force 'org.antlr:antlr4:4.10',
                'org.antlr:antlr4-runtime:4.10',
                'com.fasterxml.jackson.core:jackson-core:2.17.1',
                'com.fasterxml.jackson.core:jackson-annotations:2.17.1',
                'com.fasterxml.jackson.core:jackson-databind:2.17.1',
                'com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.17.1'
    }
}

shadowJar {
    manifest {
        attributes(["Multi-Release": true])
    }
}