asterix-app/src/test/resources/optimizerts/queries/inverted-index-join/word-jaccard-check_01.aql

/*
 * Description    : Fuzzy joins two datasets, DBLP and CSX, based on the similarity-jaccard-check function of their titles' word tokens.
 *                  DBLP has a keyword index on title, and we expect the join to be transformed into an indexed nested-loop join.
 * Success        : Yes
 */

drop dataverse test if exists;
create dataverse test;
use dataverse test;

create type DBLPType as closed {
  id: int32, 
  dblpid: string,
  title: string,
  authors: string,
  misc: string
}

create type CSXType as closed {
  id: int32, 
  csxid: string,
  title: string,
  authors: string,
  misc: string
}

create dataset DBLP(DBLPType) partitioned by key id;

create dataset CSX(CSXType) partitioned by key id;

load dataset DBLP 
using "edu.uci.ics.asterix.external.dataset.adapter.NCFileSystemAdapter"
(("path"="nc1://data/dblp-small/dblp-small-id.txt"),("format"="delimited-text"),("delimiter"=":")) pre-sorted;

load dataset CSX
using "edu.uci.ics.asterix.external.dataset.adapter.NCFileSystemAdapter"
(("path"="nc1://data/pub-small/csx-small-id.txt"),("format"="delimited-text"),("delimiter"=":"));

create index keyword_index on DBLP(title) type keyword;

write output to nc1:"rttest/inverted-index-join_word-jaccard-check_01.adm";

for $a in dataset('DBLP')
for $b in dataset('CSX')
where similarity-jaccard-check(word-tokens($a.title), word-tokens($b.title), 0.5f)[0]
      and $a.id < $b.id
return {"arec": $a, "brec": $b }