gobblin-metastore/build.gradle

// Copyright (C) 2014-2016 LinkedIn Corp. All rights reserved.
//
// Licensed under the Apache License, Version 2.0 (the "License"); you may not use
// this file except in compliance with the License. You may obtain a copy of the
// License at  http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software distributed
// under the License is distributed on an "AS IS" BASIS, WITHOUT WARRANTIES OR
// CONDITIONS OF ANY KIND, either express or implied.

apply plugin: 'java'

dependencies {
    compile project(":gobblin-api")
    compile project(path: ':gobblin-rest-service:gobblin-rest-api', configuration: 'restClient')
    compile project(":gobblin-utility")

    compile externalDependency.guava
    compile externalDependency.slf4j
    compile externalDependency.pegasus.data
    compile externalDependency.commonsDbcp
    compile externalDependency.guice
    compile externalDependency.javaxInject
    compile externalDependency.jodaTime
    
    runtime externalDependency.mysqlConnector

    testCompile externalDependency.testng
    testRuntime externalDependency.derby
}

// Begin HACK to get around POM being depenendent on the (empty) gobblin-rest-api instead of gobblin-rest-api-rest-client
def installer = install.repositories.mavenInstaller
[installer]*.pom*.whenConfigured {pom ->
    pom.dependencies.find {dep -> dep.groupId == project.group && dep.artifactId == 'gobblin-rest-api' }.artifactId = 'gobblin-rest-api-rest-client'
}
if (rootProject.publishToMaven) {
    def deployer = uploadArchives.repositories.mavenDeployer
    [deployer]*.pom*.whenConfigured {pom ->
        pom.dependencies.find {dep -> dep.groupId == project.group && dep.artifactId == 'gobblin-rest-api' }.artifactId = 'gobblin-rest-api-rest-client'
    }
}
// End HACK

configurations {
    compile {
        transitive = false
    }
}

test {
    workingDir rootProject.rootDir
}

ext.classification="library"