/**
 * Licensed to the Apache Software Foundation (ASF) under one
 * or more contributor license agreements.  See the NOTICE file
 * distributed with this work for additional information
 * regarding copyright ownership.  The ASF licenses this file
 * to you under the Apache License, Version 2.0 (the
 * "License"); you may not use this file except in compliance
 * with the License.  You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
package org.apache.hadoop.mapred;

public aspect EagerTaskInitializationListenerAspects {

  pointcut overrideJobAdded (JobInProgressListener listener, JobInProgress job) :
    call (void JobInProgressListener.jobAdded(JobInProgress)) &&
    target (listener) &&
    args (job);
  
  void around(JobInProgressListener listener, JobInProgress job) : 
    overrideJobAdded (listener, job) {
    if (listener instanceof EagerTaskInitializationListener) {
      ((EagerTaskInitializationListener)listener).ttm.initJob(job);
    } else {
      proceed(listener, job);
    }
  }

  pointcut overrideJobRemoved (JobInProgressListener listener, JobInProgress job) :
    call (void JobInProgressListener.jobRemoved(JobInProgress)) &&
    target (listener) &&
    args(job);
  
  void around(JobInProgressListener listener, JobInProgress job) : 
    overrideJobRemoved (listener, job) {
    if (listener instanceof EagerTaskInitializationListener) {
      // no-op
    } else {
      proceed(listener, job);
    }
  }
}