/*
 * Licensed to the Apache Software Foundation (ASF) under one or more
 * contributor license agreements.  See the NOTICE file distributed with
 * this work for additional information regarding copyright ownership.
 * The ASF licenses this file to You under the Apache License, Version 2.0
 * (the "License"); you may not use this file except in compliance with
 * the License.  You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

buildscript {
    ext {
        springBootVersion = '1.4.1.RELEASE'
    }

    repositories {
        jcenter()
    }

    dependencies {
        classpath("org.asciidoctor:asciidoctor-gradle-plugin:1.5.3")
    }
}

plugins {
    id 'com.github.hierynomus.license' version '0.13.1'
    id("org.nosphere.apache.rat") version "0.5.2"
    id "com.jfrog.artifactory" version "4.9.5"
    id "org.springframework.boot" version "1.4.3.RELEASE"
    id 'maven-publish'
    id 'java'
}

apply from: '../shared.gradle'
apply plugin: 'org.asciidoctor.convert'

bootRepackage {
    enabled = false
}

dependencies {
    compile(
            [group: 'org.apache.fineract.cn.provisioner', name: 'api', version: project.version],
            [group: 'org.apache.fineract.cn.provisioner', name: 'service', version: project.version],
            [group: 'org.apache.fineract.cn.anubis', name: 'test', version: versions.frameworkanubis],
            [group: 'org.apache.fineract.cn.anubis', name: 'api', version: versions.frameworkanubis],
            [group: 'org.apache.fineract.cn.identity', name: 'api', version: versions.fineractidentityservice],
            [group: 'org.apache.fineract.cn', name: 'api', version: versions.frameworkapi],
            [group: 'org.apache.fineract.cn', name: 'test', version: versions.frameworktest],
            [group: 'org.apache.fineract.cn', name: 'lang', version: versions.frameworklang],
            [group: 'org.springframework.boot', name: 'spring-boot-starter-test'],
            [group: 'org.springframework.restdocs', name: 'spring-restdocs-mockmvc'],
            [group: 'junit', name: 'junit', version: '4.12'],
            [group: 'com.opentable.components', name: 'otj-pg-embedded', version: '0.7.1']
    )
}

asciidoctor {
    sourceDir 'build/doc/asciidoc/'
    outputDir 'build/doc/html5'
    options backend: "html", doctype: "book"
    attributes "source-highlighter": "highlightjs", 'snippets': file('build/doc/generated-snippets/')
}

publishing {
    publications {
        componentTest(MavenPublication) {
            from components.java
            version project.findProperty('externalVersion') ?: project.version
        }
    }
}